> For the complete documentation index, see [llms.txt](https://docs.chjina.com/llms.txt). Markdown versions of documentation pages are available by appending `.md` to page URLs; this page is available as [Markdown](https://docs.chjina.com/it-zhi-shi-ku/ban-gong-ji-qiao/wps-you-jian-xin-jian-wen-dang-bao-cun-tan-chu-jian-rong-xing-jing-gao-wen-ti-jie-jue.md).

# WPS右键新建文档保存弹出兼容性警告问题解决

**适用版本**：WPS 11.8.2.X

**适用系统**：64位Windows系统（WPS默认安装路径）

**问题现象**：桌面右键新建Word/Excel等WPS关联文档，打开保存时弹出兼容性警告，提示文件格式包含不兼容功能，需选择是否保持格式或保留功能。

![img](/files/acc4dd2f2a1239d6aac865778d5390c37b207682)

## 一、基础解决方法：WPS自带配置修复

适用于普通用户，先通过WPS自身配置工具重新关联文件，步骤如下：

{% stepper %}
{% step %}

## 打开配置工具

打开WPS，点击左上角「WPS文字/表格/演示」，找到右上角**小齿轮图标**；
{% endstep %}

{% step %}

## 进入兼容设置

选择「配置与修复工具」→「高级」→「兼容设置」；
{% endstep %}

{% step %}

## 重新勾选兼容选项

找到兼容相关选项：**WPS Office兼容第三方系统和软件**、**与Microsoft Office 2003/2007/2010兼容**，将这些选项**全部取消勾选后重新勾选**；
{% endstep %}

{% step %}

## 重新关联文件并确认

勾选下方文件关联选项（Word/Excel/PDF/图片等），点击「确定」完成配置。

![img](/files/98c9e88fcf451d5416850a93d688e95989631e91)
{% endstep %}
{% endstepper %}

## 二、问题根源分析

若基础方法无效，大概率是**注册表项版本号不匹配**导致：

1. 右键新建文档的模板路径注册表项中，版本号`%WPSVERSION%`与实际安装的WPS版本号不一致；
2. 验证方法：WPS界面按`F12`，若实际文件格式为`txt`，可确定是注册表问题；
3. 关键注册表路径（关联新建文档模板）：

   ```
   HKEY_CLASSES_ROOT\.doc\Word.Document.8\ShellNew
   ```

   正常项值应为：

   ```
   C:\Program Files (x86)\Kingsoft\WPS Office\%WPSVERSION%\office6\mui\zh_CN\templates\newfile.doc
   ```
4. WPS安装/升级时未自动校验并修复注册表项，覆盖安装、卸载重装均无法解决该问题。

## 三、批处理脚本修复（手动指定版本）

通过批处理修改注册表，匹配实际WPS版本号，**需以管理员身份运行**。

### 脚本代码

将第一行`11.8.2.X`替换为自身WPS实际版本号：

```bat
set "version=11.8.2.X"
set /p "user_confirm=是否使用预设版本号 %version%? (Y/N): "
if /i "%user_confirm%"=="N" (
    set /p "version=请输入自定义的版本号: "
)
reg delete "HKEY_CLASSES_ROOT\.doc\Word.Document.8\ShellNew" /f
reg delete "HKEY_CLASSES_ROOT\.docx\Word.Document.12\ShellNew" /f
reg delete "HKEY_CLASSES_ROOT\.xls\Excel.Sheet.8\ShellNew" /f
reg delete "HKEY_CLASSES_ROOT\.xlsx\Excel.Sheet.12\ShellNew" /f 
reg add "HKEY_CLASSES_ROOT\.doc\Word.Document.8\ShellNew" /v "FileName" /t REG_SZ /d "C:\Program Files (x86)\Kingsoft\WPS Office\%version%\office6\mui\zh_CN\templates\newfile.doc" /f
reg add "HKEY_CLASSES_ROOT\.docx\Word.Document.12\ShellNew" /v "NullFile" /t REG_SZ /d "" /f
reg add "HKEY_CLASSES_ROOT\.xls\Excel.Sheet.8\ShellNew" /v "FileName" /t REG_SZ /d "C:\Program Files (x86)\Kingsoft\WPS Office\%version%\office6\mui\zh_CN\templates\newfile.xls" /f
reg add "HKEY_CLASSES_ROOT\.xlsx\Excel.Sheet.12\ShellNew" /v "FileName" /t REG_SZ /d "C:\Program Files (x86)\Kingsoft\WPS Office\%version%\office6\mui\zh_CN\templates\newfile.xlsx" /f
```

### 操作步骤

1. 记事本复制上述代码，保存为`*.bat`格式；
2. 右键该文件，选择「以管理员身份运行」；
3. 按提示确认版本号，执行完成后，新建文档测试是否解决问题。

## 四、批处理脚本修复（自动识别版本）

优化版脚本，可**自动读取注册表中的WPS版本号**，无需手动输入，同样**以管理员身份运行**。

### 核心注册表路径（WPS版本号存储位置）

```
HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Kingsoft Office\DisplayVersion
```

### 脚本代码

```bat
@echo off
setlocal 
REM 输出警告声明
echo ————————WARNING—————————
echo 本脚本将对注册表进行操作，请确保您有足够的权限！
echo 对注册表的操作不可逆，请您确定！
echo ————————WARNING—————————
echo. 
set "regPath=HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Kingsoft Office"
set "regKey=DisplayVersion"
for /f "tokens=3" %%A in ('reg query "%regPath%" /v "%regKey%" 2^>nul') do (
    set "version=%%A"
) 
REM 询问用户是否使用默认版本号
set /p "user_confirm=是否使用当前WPS版本号%version%? (Y/N): " 
REM 根据用户输入决定版本号
if /i "%user_confirm%"=="N" (
    set /p "version=请输入自定义的版本号: "
) 
echo ——————————————————————
echo 即将删除原本的注册表项Word.Document.8、Word.Document.12、Excel.Sheet.8、Excel.Sheet.12 
REM 删除注册表项
reg delete "HKEY_CLASSES_ROOT\.doc\Word.Document.8\ShellNew" /f
reg delete "HKEY_CLASSES_ROOT\.docx\Word.Document.12\ShellNew" /f
reg delete "HKEY_CLASSES_ROOT\.xls\Excel.Sheet.8\ShellNew" /f
reg delete "HKEY_CLASSES_ROOT\.xlsx\Excel.Sheet.12\ShellNew" /f 
REM 重新添加注册表项，使用选择或默认的版本号
echo ——————————————————————
echo 即将重新添加注册表项，注册表项内容如下：
echo 向HKEY_CLASSES_ROOT\.doc\Word.Document.8\ShellNew\FileName添加值C:\Program Files (x86)\Kingsoft\WPS Office\%version%\office6\mui\zh_CN\templates\newfile.doc
echo 向HKEY_CLASSES_ROOT\.doc\Word.Document.12\ShellNew\FileName添加空值
echo 向HKEY_CLASSES_ROOT\.doc\Excel.Sheet.8\ShellNew\FileName添加值C:\Program Files (x86)\Kingsoft\WPS Office\%version%\office6\mui\zh_CN\templates\newfile.xls
echo 向HKEY_CLASSES_ROOT\.doc\Excel.Sheet.12\ShellNew\FileName添加值C:\Program Files (x86)\Kingsoft\WPS Office\%version%\office6\mui\zh_CN\templates\newfile.xlsx 
reg add "HKEY_CLASSES_ROOT\.doc\Word.Document.8\ShellNew" /v "FileName" /t REG_SZ /d "C:\Program Files (x86)\Kingsoft\WPS Office\%version%\office6\mui\zh_CN\templates\newfile.doc" /f
reg add "HKEY_CLASSES_ROOT\.docx\Word.Document.12\ShellNew" /v "NullFile" /t REG_SZ /d "" /f
reg add "HKEY_CLASSES_ROOT\.xls\Excel.Sheet.8\ShellNew" /v "FileName" /t REG_SZ /d "C:\Program Files (x86)\Kingsoft\WPS Office\%version%\office6\mui\zh_CN\templates\newfile.xls" /f
reg add "HKEY_CLASSES_ROOT\.xlsx\Excel.Sheet.12\ShellNew" /v "FileName" /t REG_SZ /d "C:\Program Files (x86)\Kingsoft\WPS Office\%version%\office6\mui\zh_CN\templates\newfile.xlsx" /f 
echo 全部操作完成！
pause 
endlocal
```

### 操作步骤

1. 记事本复制代码，保存为文件编码为 ANSI`*.bat`格式；
2. 右键「以管理员身份运行」，脚本自动读取WPS版本号；
3. 按提示确认版本号（可手动修改），执行完成后测试即可。

## 五、注意事项

1. 上述脚本**仅适用于64位系统+WPS默认安装路径**，大规模部署需先修改调试；
2. 注册表操作有风险，执行前建议备份注册表相关项；
3. 脚本运行后若仍有问题，检查WPS安装路径是否为`C:\Program Files (x86)\Kingsoft\WPS Office\`，若路径不同需对应修改脚本中的路径。